lambdaway :: dragon

4 | list | login |load

| |

{center
{svg 
 {@ width="580px" height="580px"
    style="box-shadow:0 0 8px #888;"}
 {path {@ d="M {turtle 130 130 0 {dcr 2 360}}" {stroke 20 #ccc}}}
 {path {@ d="M {turtle 130 130 0 {dcr 6 360}}" {stroke 10 #888}}}
 {path {@ d="M {turtle 130 130 0 {dcr 12 360}}" {stroke 1 #f00}}}
}}

_h1 dragon curve | [[hilbert]] | [[fern]]

_ul [[http://rosettacode.org/wiki/Dragon_curve|http://rosettacode.org/wiki/Dragon_curve]]

_h2 1) two twinned recursive functions

{prewrap
'{def dcr 
 {lambda {:step :length}
  {let { {:step {- :step 1}}
         {:length {/ :length 1.41421}}      // length/√2
       } {if {> :step 0}
          then T45
               {dcr :step :length}
               T-90
               {dcl :step :length}
               T45
          else T45
               M:length
               T-90
               M:length
               T45
         } 
}}}
-> {def dcr 
 {lambda {:step :length}
  {let { {:step {- :step 1}}
         {:length {/ :length 1.41421}}
       } {if {> :step 0}
          then T45 {dcr :step :length} T-90 {dcl :step :length} T45
          else T45 M:length T-90 M:length T45} }}}
 
'{def dcl 
 {lambda {:step :length}
  {let { {:step {- :step 1}}
         {:length {/ :length 1.41421}}
       } {if {> :step 0}
          then T-45
               {dcr :step :length}
               T90
               {dcl :step :length}
               T-45
          else T-45
               M:length
               T90
               M:length
               T-45
         } 
}}}
-> {def dcl {lambda {:step :length}
  {let { {:step {- :step 1}}
         {:length {/ :length 1.41421}}
       } {if {> :step 0}
          then T-45 {dcr :step :length} T90 {dcl :step :length} T-45
          else T-45 M:length T90 M:length T-45} }}}
}

_p The word {code Tθ} rotates the drawing direction of a pen from {b θ} degrees and the word {code Md} moves it on {b d} pixels. The call {code '{dcr 10 360}} produces {b 4093} words begining with 
{prewrap T45 T45 T45 T45 T45 T45 T45 T45 T45 T45 M11.250283388970585 T-90 M11.250283388970585 T45 T-90 T-45 M11.250283388970585 T90 M11.250283388970585 ...
}

_h2 2) the SVG context

_p Lambdatalk comes with a primitive, {code turtle}, translating the previous sequence of words into a sequence of SVG points [{code x0 y0 x1 y2 ... xn yn}] feeding the "d" attribute of a SVG path.

{pre
'{def stroke
 {lambda {:w :c}
  fill="transparent" stroke=":c" stroke-width=":w"}}
-> {def stroke {lambda {:w :c} fill="transparent" stroke=":c" stroke-width=":w"}}

'{svg 
 {@ width="580px" height="580px"
    style="box-shadow:0 0 8px #888;"}
 {path {@ d="M {turtle 130 130 0 {dcr 2 360}}" {stroke 20 #ccc}}}
 {path {@ d="M {turtle 130 130 0 {dcr 6 360}}" {stroke 10 #888}}}
 {path {@ d="M {turtle 130 130 0 {dcr 10 360}}" {stroke 1 #000}}}
}
}