lambdaway :: eric

1 | list | login |load

| |

_h2 [[eric_dobbs]] | [[eric_dobbs2]] | eric_dobbs3

_p We work with a lambdatalk reduced to {b lambdas & defs}, without any {b if & let} syntactic sugar and with primitives on numbers.

_h2 1) defining basic bricks

{pre
'{def TRUE {lambda {:a :b} :a}}  -> {def TRUE {lambda {:a :b} :a}}
'{def FALSE {lambda {:a :b} :b}} -> {def FALSE {lambda {:a :b} :b}}
'{def IF {lambda {:a :b :c} {:a :b :c}}} -> {def IF {lambda {:a :b :c} {:a :b :c}}}

'{def PAIR {lambda {:a :b :c} {:c :a :b}}} -> {def PAIR {lambda {:a :b :c} {:c :a :b}}}
'{def LEFT {lambda {:c} {:c TRUE}}} -> {def LEFT {lambda {:c} {:c TRUE}}}
'{def RIGHT {lambda {:c} {:c FALSE}}} -> {def RIGHT {lambda {:c} {:c FALSE}}}

'{def NIL {lambda {:a} TRUE}} -> {def NIL {lambda {:a} TRUE}}
'{def NIL? {lambda {:c} {:c {lambda {:a :b} FALSE}}}} -> {def NIL? {lambda {:c} {:c {lambda {:a :b} FALSE}}}}

'{def ZERO NIL} -> {def ZERO NIL}
'{def ONE {PAIR • NIL}} -> {def ONE {PAIR • NIL}}
'{def TWO {PAIR • {PAIR • NIL}}} -> {def TWO {PAIR • {PAIR • NIL}}}
'{def THREE {PAIR • {PAIR • {PAIR • NIL}}}} -> {def THREE {PAIR • {PAIR • {PAIR • NIL}}}} 
}

_h2 2) defining the fractal function

{pre
'{def fractal
 {lambda {:curv :lev :len}       
  {{IF {NIL? :lev}
   {lambda {:curv :lev :len} M:len}
   {lambda {:curv :lev :len}
    {fractal.repeat :curv {RIGHT :lev} {/ :len 3} {:curv}} }} 
     :curv :lev :len}}}
-> {def fractal
 {lambda {:curv :lev :len}       
  {{IF {NIL? :lev}
   {lambda {:curv :lev :len} M:len}
   {lambda {:curv :lev :len}
    {fractal.repeat :curv {RIGHT :lev} {/ :len 3} {:curv}} }} 
     :curv :lev :len}}}

'{def fractal.repeat
 {lambda {:curv :lev :len :command}
  {{IF {NIL? :command}
   {lambda {:curv :lev :len :command} } 
   {lambda {:curv :lev :len :command}
    {fractal :curv :lev :len} {LEFT :command} 
     {fractal.repeat :curv :lev :len {RIGHT :command}}}}
   :curv :lev :len :command}}}
-> {def fractal.repeat
 {lambda {:curv :lev :len :command}
  {{IF {NIL? :command}
   {lambda {:curv :lev :len :command} } 
   {lambda {:curv :lev :len :command}
    {fractal :curv :lev :len} {LEFT :command} 
     {fractal.repeat :curv :lev :len 
                     {RIGHT :command}}}}
   :curv :lev :len :command}}}
}

_h2 3) defining the PEANO curve

_p The curve is defined as a list of commands {b M:length, T:angle} embedded inside a lambda.

{pre
'{def randangle
 {lambda {:a :b}
  {{lambda {:a :b :t} 
    {+ {* {- 1 :t} :a} {* :t :b}}
   } :a :b {random}}}}
-> {def randangle
 {lambda {:a :b}
  {{lambda {:a :b :t} 
    {+ {* {- 1 :t} :a} {* :t :b}}
   } :a :b {random}}}}
  
'{def PEANO
 {lambda {} 
  {{lambda {:ang}
   {PAIR T-:ang
   {PAIR T:ang
   {PAIR T:ang
   {PAIR T:ang
   {PAIR T-:ang
   {PAIR T-:ang
   {PAIR T-:ang
   {PAIR T:ang 
   {PAIR T0 NIL}}}}}}}}} 
  } {randangle 85 95}}}}
-> {def PEANO
 {lambda {} 
  {{lambda {:ang}
   {PAIR T-:ang
   {PAIR T:ang
   {PAIR T:ang
   {PAIR T:ang
   {PAIR T-:ang
   {PAIR T-:ang
   {PAIR T-:ang
   {PAIR T:ang 
   {PAIR T0 NIL}}}}}}}}} 
  } {randangle 85 95}}}}
}

_h2 4) drawing

{pre
'{svg    
 {@ width="580" height="580" style="box-shadow:0 0 8px #000;"}
  
 {polyline
  {@ points="{turtle 280 30 0 {fractal PEANO {ONE} 500}}"
     stroke="#888" fill="transparent" stroke-width="5"}}

{polyline
  {@ points="{turtle 280 030 0 {fractal PEANO {THREE} 500}}"
     stroke="#0f0" fill="transparent"}}
}
}

_p Result

{svg    
 {@ width="580" height="580" style="box-shadow:0 0 8px #000;"}
  
 {polyline
  {@ points="{turtle 280 30 0 {fractal PEANO {ONE} 500}}"
     stroke="#888" fill="transparent" stroke-width="5"}}

{polyline
  {@ points="{turtle 280 030 0 {fractal PEANO {THREE} 500}}"
     stroke="#0f0" fill="transparent"}}
}

_h2 next step

_p The {b fractal} function written at the λ-calculus level, as a single s-expression. 
  
{style 
pre { box-shadow:0 0 8px #000; padding:10px; }
}