lambdaway :: fractal

2 | list | login |load

| |

_h1 fractal tree | [[fern]] | [[hilbert]] | [[tree]]

{{hide}
{def tree 
 {lambda {:e :s :k :a :b}
  {if {< :s :e}
   then 
   else M:s T:a     {tree :e {* :k :s} :k :a :b}
        T-{+ :a :b} {tree :e {* :k :s} :k :a :b}
        T:b M-:s }}}

{def T {tree 2 200 {/ 2 3} 15 45}}
}

{svg 
 {@ width="580px" height="580px" style="box-shadow:0 0 8px #000;"}
 {polyline 
  {@ points="{turtle 230 580 180 {T}}"
     fill="transparent" stroke="#888" stroke-width="5"}}
 {polyline 
  {@ points="{turtle 230 580 180 {T}}"
     fill="transparent" stroke="#fff" stroke-width="1"}}
}

_h2 code

_ul Following [[rosetta.org|http://www.rosettacode.org/wiki/Fractal_tree]] the task is to generate and draw a fractal tree.

_ul Draw the trunk
_ul At the end of the trunk, split by some angle and draw two branches
_ul Repeat at the end of each branch until a sufficient level of branching is reached

{pre 
'{def tree 
 {lambda {:e     // last branch length
          :s     // trunks length
          :k     // ratio between two following branches
          :a     // rotate left
          :b}    // rotate right
  {if {< :s :e}
   then 
   else M:s T:a
        {tree :e {* :k :s} :k :a :b}
        T-{+ :a :b}
        {tree :e {* :k :s} :k :a :b}
        T:b M-:s }}}
}

_p Calling this function generates a sequence of commands mooving a pen: 
_ul {code Tθ} rotates the drawing direction "θ" degrees from the previous one 
_ul and {code Md} draws a segment "d" pixels in this direction.

{pre
'{def T {tree 1 190 {/ 2 3} 15 45}} 
}
_p produces {b 40995} words beginning with:

{prewrap
M190 T15 M126.66666666666666 T15 M84.44444444444443 T15 M56.29629629629628 T15 M37.53086419753085 T15 M25.020576131687235 T15 M16.680384087791488 T15 M11.120256058527659 T15 M7.413504039018439 T15 M4.942336026012292 T15 M3.2948906840081946 ...
}

_p These words are sent to a the {code turtle} lambdatalk primitive which is a graphic device translating the sequence of {code Md} and {code Tθ} into a sequence of SVG points {code x0 y0 x1 y1 ... xn yn} which will feed the {code points} attribute of a {code polyline} SVG element:

{pre
'{svg 
 {@ width="580px" height="580px" style="box-shadow:0 0 8px #000;"}
 {polyline 
  {@ points="{turtle 230 570 180 {T}}"
     fill="transparent" stroke="#888" stroke-width="5"}}
 {polyline 
  {@ points="{turtle 230 570 180 {T}}"
     fill="transparent" stroke="#fff" stroke-width="1"}}
}
}