lambdaway :: koch

5 | list | login |load

| |

_h1 [[fractal_tree]] | [[fern]] | koch | [[sierpinsky]]

_ul [[http://rosettacode.org/wiki/Koch_curve|http://rosettacode.org/wiki/Koch_curve]]

_p We build a single function, {code koch}, following the definition of the KOCH curve:

{prewrap
'{def koch 
 {lambda {:d :n}                  // longueur et niveau de récursion
  {if {= :n 0}                    // si n = 0
   then M:d                       // alors avance de d et stop
   else                           // sinon
       {koch {/ :d 3} {- :n 1}}   // divise d par 3 et décrémente n
        T-60                      // tourne de -60°
       {koch {/ :d 3} {- :n 1}}   // divise d par 3 et décrémente n
        T120                      // tourne de 120°
       {koch {/ :d 3} {- :n 1}}   // divise d par 3 et décrémente n
        T-60                      // tourne de -60°
       {koch {/ :d 3} {- :n 1}}   // divise d par 3 et décrémente n
}}}

-> {def koch 
 {lambda {:d :n}
  {if {< :n 1}
   then M:d
   else {koch {/ :d 3} {- :n 1}} T-60
        {koch {/ :d 3} {- :n 1}} T120
        {koch {/ :d 3} {- :n 1}} T-60
        {koch {/ :d 3} {- :n 1}} }}}
}

_p Note that other angles can be tested, for instance {code T-60 T120 T-60} can be replaced by {code T-50 T120 T-50},  {code T-350 T130 T-30} and so on.

_p Calling this function on a length and a level of recursion produces a sequence of words, {code Md, Ta}, where {b d} is a length in pixels and {b a} is an angle in degrees. Here is the beginning of the sequence of {b 511} words:

{prewrap
'{def K {koch 300 4}}
-> {def K {koch 300 4}} = M3.703703703703704 T-60 M3.703703703703704 T120 M3.703703703703704 T-60 M3.703703703703704 T-60 M3.703703703703704 T-60 M3.703703703703704 T120 M3.703703703703704 T-60 M3.703703703703704 T120 M3.703703703703704 T-60 M3.703703703703704 T120 M3.703703703703704 T-60 M3.703703703703704 T-60 
...
}

_p These words are translated by the {code '{turtle}} lambdatalk primitive into a sequence of SVG formated points, {code x y},  feeding the {code points} attribute of a {code polyline} displayes in a SVG context:

{prewrap
'{svg {@ width="580" height="580" style="box-shadow:0 0 8px #000;"}
 {polyline  {@ points="{turtle 140 140 0 {K}}"  
               stroke="#f00" fill="transparent"}}
 {polyline  {@ points="{turtle 140 440 90 {K}}"  
               stroke="#0f0" fill="transparent"}}
 {polyline  {@ points="{turtle 440 440 180 {K}}"  
               stroke="#00f" fill="transparent"}}
 {polyline  {@ points="{turtle 440 140 270 {K}}"  
               stroke="#ff0" fill="transparent"}} 
}
}

{svg {@ width="580" height="580" style="background:#222; box-shadow:0 0 8px #000;"}
 {polyline  {@ points="{turtle 140 140 0 {K}}"  
               stroke="#f00" fill="transparent"}}
 {polyline  {@ points="{turtle 140 440 90 {K}}"  
               stroke="#0ff" fill="transparent"}}
 {polyline  {@ points="{turtle 440 440 180 {K}}"  
               stroke="#ff0" fill="transparent"}}
 {polyline  {@ points="{turtle 440 140 270 {K}}"  
               stroke="#f0f" fill="transparent"}}
}